I have observed that the GH2 encoder performance is quite variable at varying luma levels and image complexity. I authored this script to look into this and I am happy with how it turned out. It might even come in handy for looking at GH3 footage.

# Better Living through Visualisation 0.2 by vicx
# An Avisynth script inspired by the discussions at http://personal-view.com  
# Visualise more plainly see the effects of quantisation and intra prediction at different luma levels using Avisynth
#
# Requires Avisynth or an Avisynth host - Tested with Avisynth 2.6 (x86).
# For tweaking scripts I use and reccommend AvsPmod Ver 2.3  http://forum.doom9.org/showthread.php?t=153248.
# It is easy to take screenshots inside AvsPmod.
# When I want to share noise in motion I open the avs file with AnotherGui http://www.stuudio.ee/anothergui/ and render to a 6mbps X264 preset 
# Presets available from here http://www.stuudio.ee/anothergui/Presets.html
#
# Brought to you by the number 4
# watch?v=7XefWDGHtNA 

# If your file won't open Google LAVfilters / If you want fullsize windows remove ReduceBy2()
source = DirectShowSource("F:\___Video\New folder\00129.MTS")
#source = Imagesource("F:\___Photo\image.png")
global clip = source.converttoYV12(matrix="Rec709").ReduceBy2()

function Render_Window(clip c, int min_luma, int max_luma,string label, int label_color, int label_halo)
{
Range = clip.Limiter(min_luma,max_luma,min_chroma=0, max_chroma=255, show="luma" )
Range_Luma = Range.histogram("luma")
Range_clip = overlay(Range_Luma,clip,0,0,clip,chroma_background,"blend")
Range_clip_labeled = Range_clip.Subtitle(label + " = " + string(min_luma) + "-" + string(max_luma), font="Tahoma", size=20, text_color=label_color, halo_color=label_halo, align=9)
return Range_clip_labeled
}

#chroma_background is 0.0-1.0 and is how bright the background appears behind the luma maps
global chroma_background = 1

#Set this lower than your source to slow things down if you want
framerate = 24

#White/Blacklimit you could make 16,235 but 0,255 makes sure you catch everything
black_limit = 0 
white_limit = 255 

#Set the luma limits for the four windows 
mud_limit = 32
coarse_limit = 128
fine_limit = 128

#Overlay Highlights in green
clip_limit = clip.Limiter(min_luma=0,max_luma=234,min_chroma=0, max_chroma=255, show="luma" )
clip_mask = clip_limit.ConverttoRGB32.ColorKeyMask($00FF00)
clip_mask = Mask(clip_limit.ConverttoRGB32(), clip_mask.ConverttoRGB32())

#Render Windows
Top_Left = clip.Subtitle( "Original", font="Tahoma", size=20, text_color=$FFFF00, halo_color=$000000, align=9).converttoRGB32.layer(clip_mask).ConvertToYV12
Top_Right = Render_Window(clip, fine_limit, white_limit, "Fine Mids and Highlights Luma ", $FFFFFF,$000000)
Bottom_Left = Render_Window(clip, black_limit, mud_limit, "Mud Luma ", $555555, $DDDDDD)
Bottom_Right = Render_Window(clip, mud_limit, fine_limit, "Coarse Mids Luma ", $BBBBBB, $000000)

#Arrange Windows
StackVertical(StackHorizontal(Top_Left,Top_Right) ,StackHorizontal(Bottom_Left,Bottom_Right) )

#EOF

I attach some images which are NOT commentary about the GH2 encoder. I just included them to demonstrate the script using a low luma image and a high luma image.

I also attach an image of kitchen re-visualised with a basic avisynth one liner.

 DirectShowSource("F:\___Video\New folder\kitchen.MTS").histogram("luma")